ABACOM - ELECTRONIC SOFTWARE

Code: Alles auswählen

EnableExplicit

Structure sDLLParams
  DLLParam.d[101]
EndStructure

; return number of input channels...
ProcedureDLL.a CNumInputsEx(*PUser.sDLLParams)

  Protected inputs.a

  inputs = *PUser\DLLParam[0]

  If inputs < 2
    inputs = 2
  ElseIf inputs > 60
    inputs = 60
  EndIf

  ProcedureReturn inputs
EndProcedure

; return number of output channels...
ProcedureDLL.a CNumOutputsEx(*PUser.sDLLParams)

  Protected outputs.a

  outputs = 3

  ProcedureReturn outputs
EndProcedure

; return name for each input...
ProcedureDLL GetInputName(Channel.a, *Name.i)

  Protected GetInputName.s

  GetInputName = "E" + Str(Channel + 1)

  PokeS(*Name, GetInputName, -1, #PB_Ascii)

EndProcedure

; return name for each output...
ProcedureDLL GetOutputName(Channel.a, *Name.i)

  Protected GetOutputName.s

  If Channel = 0
    GetOutputName = "Min"
  ElseIf Channel = 1
    GetOutputName = "Max"
  ElseIf Channel = 2
    GetOutputName = "Mittel"
  Else
    GetOutputName = "U"
  EndIf

  PokeS(*Name, GetOutputName, -1, #PB_Ascii)

EndProcedure

; check inputs and set outputs while running...
ProcedureDLL CCalculate(*PInput.sDLLParams, *POutput.sDLLParams, *PUser.sDLLParams)

  Protected inputs.a, min.d, max.d, summe.d, mittel.d, n.i

  min    = 0
  max    = 0
  mittel = 0

  inputs = *PUser\DLLParam[0]

  If inputs > 1

    min    = *PInput\DLLParam[0]
    max    = *PInput\DLLParam[0]
    mittel = 0

    For n = 1 To inputs - 1
      If min > *PInput\DLLParam[n]
        min = *PInput\DLLParam[n]
      EndIf
    Next n

    For n = 1 To inputs - 1
      If max < *PInput\DLLParam[n]
        max = *PInput\DLLParam[n]
      EndIf
    Next n

    For n = 0 To inputs - 1
      summe = summe + *PInput\DLLParam[n]
    Next n

    mittel = summe / inputs

  EndIf

  *POutput\DLLParam[0] = min
  *POutput\DLLParam[1] = max
  *POutput\DLLParam[2] = mittel

EndProcedure

; called when project is started...
ProcedureDLL CSimStart(*PInput.sDLLParams, *POutput.sDLLParams, *PUser.sDLLParams)

  ; nothing to do...

EndProcedure

; called when project is stopped...
ProcedureDLL CSimStop(*PInput.sDLLParams, *POutput.sDLLParams, *PUser.sDLLParams)

  ; nothing to do...

EndProcedure

; called when button CONFIGURE is pressed in dialogue...
ProcedureDLL CConfigure(*PUser.sDLLParams)

  Enumeration
    #Window_0
  EndEnumeration

  Enumeration
    #Text_Anzahl
    #String_Anzahl
    #Button_OK
    #Button_Abbrechen
  EndEnumeration

  Enumeration
    #Arial10
  EndEnumeration

  Protected Event.i, EventWindow.i, EventGadget.i, EventType.i, EventMenu.i, quit.i
  Protected inputs.a
    
  inputs = *PUser\DLLParam[0]

  If inputs < 2
    inputs = 2
  ElseIf inputs > 60
    inputs = 60
  EndIf
  
  LoadFont(#Arial10, "Arial" , 10)
  
  If OpenWindow(#Window_0, 536, 228, 170, 110, "MinMaxMittel", #PB_Window_SystemMenu | #PB_Window_TitleBar)

    TextGadget(#Text_Anzahl, 25, 25, 45, 30, "Anzahl:")
    StringGadget(#String_Anzahl, 85, 20, 60, 25, "", #PB_Text_Right)
    ButtonGadget(#Button_OK, 20, 60, 45, 30, "OK")
    ButtonGadget(#Button_Abbrechen, 70, 60, 75, 30, "Abbrechen")

    SetGadgetFont(#Text_Anzahl, FontID(#Arial10))
    SetGadgetFont(#String_Anzahl, FontID(#Arial10))

    SetGadgetText(#String_Anzahl, Str(inputs))

    Repeat

      Event       = WaitWindowEvent()
      EventGadget = EventGadget()
      EventType   = EventType()
      EventWindow = EventWindow()

      Select Event

        Case #PB_Event_Gadget

          If EventGadget = #String_Anzahl
            ;
          ElseIf EventGadget = #Button_OK
            inputs = Val(GetGadgetText(#String_Anzahl))
            quit   = 1
          ElseIf EventGadget = #Button_Abbrechen
            quit = 1
          EndIf

        Case #PB_Event_CloseWindow

          quit = 1

      EndSelect

    Until quit = 1

    CloseWindow(#Window_0)

  EndIf

  If inputs < 2
    inputs = 2
  ElseIf inputs > 60
    inputs = 60
  EndIf

  *PUser\DLLParam[0] = inputs

EndProcedure