ABACOM - ELECTRONIC SOFTWARE

Code: Alles auswählen

; MultiSwitch.pb

EnableExplicit

Global inp.a, def.a

Structure sDLLParams
  DLLParam.d[101]
EndStructure

; return number of input channels...
ProcedureDLL.a CNumInputsEx(*PUser.sDLLParams)

  Protected Inputs.a

  If inp > 1 And inp < 10
    Inputs = inp
  Else
    Inputs = 2
  EndIf

  ProcedureReturn Inputs
EndProcedure

; return number of output channels...
ProcedureDLL.a CNumOutputsEx(*PUser.sDLLParams)

  Protected Outputs.a

  If inp > 1 And inp < 10
    Outputs = inp
  Else
    OutPuts = 2
  EndIf

  ProcedureReturn Outputs
EndProcedure

; return name for each input...
ProcedureDLL GetInputName(Channel.a, *Name.i)

  Protected GetInputName.s

  GetInputName = "E" + Str(Channel + 1)

  PokeS(*Name, GetInputName, -1, #PB_Ascii)

EndProcedure

; return name for each output...
ProcedureDLL GetOutputName(Channel.a, *Name.i)

  Protected GetOutputName.s

  GetOutputName = "A" + Str(Channel + 1)

  PokeS(*Name, GetOutputName, -1, #PB_Ascii)

EndProcedure

; check inputs and set outputs while running...
ProcedureDLL CCalculate(*PInput.sDLLParams, *POutput.sDLLParams, *PUser.sDLLParams)

  Protected i.i, j.i

  For i = 0 To 8

    If *PInput\DLLParam[i] > 2.5

      For j = 0 To 8
        *POutput\DLLParam[j] = 0
      Next j

      *PUser\DLLParam[i]   = 5
      *POutput\DLLParam[i] = 5

    EndIf

  Next i

EndProcedure

; called when project is started...
ProcedureDLL CSimStart(*PInput.sDLLParams, *POutput.sDLLParams, *PUser.sDLLParams)

  Protected i.i
  
  For i = 0 To 8
    *POutput\DLLParam[i] = 0
  Next i  
  
  If def > 0 And def < 10
    *POutput\DLLParam[def - 1] = 5
  EndIf
    
EndProcedure

; called when project is stopped...
ProcedureDLL CSimStop(*PInput.sDLLParams, *POutput.sDLLParams, *PUser.sDLLParams)
  
  ; nothing to do...
  
EndProcedure

; called when button CONFIGURE is pressed in dialogue...
ProcedureDLL CConfigure(*PUser.sDLLParams)

  MessageRequester("Configure", "Nothing to configure")

EndProcedure


Procedure ReadIniFile()

  Protected path$

  path$ = GetPathPart(ProgramFilename())
  If Right(path$, 1) <> "\"
    path$ = path$ + "\"
  EndIf

  OpenPreferences(path$ + "MultiSwitch.ini")

  PreferenceGroup("MultiSwitch")

  inp = Val(ReadPreferenceString("Inputs", "2"))
  def = Val(ReadPreferenceString("Default", "0"))

  ClosePreferences()

EndProcedure


ProcedureDLL AttachProcess(Instance.i)

  ReadIniFile()

EndProcedure